Een feest en verjaardagen kalender maken.

We maken eerst een keuzemenu voor de jaartallen.
Selecteer cel C2 en ga op het lint naar “Gegevens” en kies “Gegevensvalidatie”.
In het venster “Gegevensvalidatie kies je bij “Toestaan” voor “Lijst”(1) en in het invulvak “Bron” typ je achtereenvolgend de jaartallen 2011 tot en met bv. 2020 gescheiden door puntkomma(2)  en klik OK.

Ons keuzemenu van cel C2.

Neem de gegevens over van de cellen B2 tot en met B18 van onderstaande afbeelding ,de cellen B2 en C2 samenvoegen en centreren, maak de cellen C2 tot en met C19, C22 en C23 op met de aangepaste notatiecode dddd d mmmm .

In cel C5 gaan we de dag weergeven voor Nieuwjaar met de formule =DATUM.
De functie DATUM(jaar;maand;dag) heeft 3 parameters:
jaar, maand, en dag.
We nemen als parameter “jaar” de celinhoud van cel C2,
Als maand nemen  we 1(eerste maand van het jaar)
En als dag 1 (eerste dag van de maand).
De formule is dan =DATUM(C2,1,1).

In cel C6 komt de datum voor het berekenen van Pasen.
Pasen is niet elk jaar op de zelfde zondag, maar op de eerste zondag die volgt op de volle maan na het begin van de lente, Er zijn talrijke formules geschreven voor het berekenen van Pasen gaande van 54 tekens tot meer dan 250 tekens, we gebruiken uiteraard de kortste formule.

=VAST((“4/”&jaartal)/7+REST(REST(jaartal;19)*19-7;30)*14%;0)*7-6.
We vervangen hier jaartal door de celverwijzing C2, want daar vinden we het jaartal terug,
De formule voor cel C6 is dan
=VAST((“4/”&C2)/7+REST(REST(C2;19)*19-7;30)*14%;0)*7-6

Cel C7 (2de paasdag)  =C6+1
Cel C8 (feest van de arbeid) =DATUM(C2;5;1)
Cel C9 (OLH hemelvaart) =C6+39
Cel C10 (Pinksteren) =C6+49
Cel C11 (2de pinksterdag) =C10+1
Cel C12 (Nationale feestdag BE) =DATUM(C2;7;21)
Cel C13 (OLV hemelvaart) =DATUM(C2;8;15)
Cel C14 (Allerheiligen) =DATUM(C2;11;1)
Cel C15 (Allerzielen) =C14+1
Cel C16 (Wapenstilstand) =DATUM(C2;11;11)
Cel C17 (Kerstmis) =DATUM(C2;12;25)
Cel C18 (2de kerstdag)=C17+1
Cel C19 (Laatste dag) =DATUM(C2;12;31)

Cel C22 (Begin zomertijd, de zomertijd begint de laatste zondag van maart) we gebruiken hiervoor de functies Datum en Weekdag.
=DATUM(C2;3;31)-WEEKDAG(DATUM(C2;3;31))+1
De formule werkt als volgt:
in dit voorbeeld is de inhoud van cel C2  2011, dan is =DATUM(C2;3;31)  donderdag 31 maart 2011(de laatste dag van maart).
WEEKDAG(DATUM(C2;3;31)) de functie WEEKDAG kent een nummer toe van 1 tot 7 voor de dagen van de week, zondag = 1, maandag = 2 enz. dus WEEKDAG(donderdag 31 maart 2011) is 5.
=DATUM(C2;3;31)-WEEKDAG(DATUM(C2;3;31))+1  donderdag 31 maart min 5 dagen  =zaterdag 26 maart 2011 plus 1 =zondag 27 maart (de laatste zondag van maart).
Cel C23 ( begin wintertijd)=DATUM(C2;10;31)-WEEKDAG(DATUM(C2;10;31))+1

Je kan deze lijst natuurlijk nog uitbreiden met bv. verjaardagen en andere speciale gelegenheden.

Ter informatie: swotster.com denkt aan zijn cursisten, denk ook aan swotster.com

Cursussen

• Downloading iPad Apps
• Lesson 1: Introduction to Publisher
• Lesson 65: File Formats