Hoofdlettergevoelig zoeken

We kennen nu wel allemaal de functie = VERT.ZOEKEN, maar het nadeel van deze functie is dat ze niet hoofdlettergevoelig is. We kunnen dit zien in onderstaand voorbeeld: met de formule voor de cel F2 =VERT.ZOEKEN($D$1;$A$1:$B$4;2;0) (exact zoeken) (1) zoeken we “abcde” en krijgen als resultaat “1” en voor cel F3 =VERT.ZOEKEN($D$1;$A$1:$B$4;2;1) (zoeken met benadering) (2) krijgen als resultaat “4” terwijl het juiste antwoord “3” is.
Dat komt omdat =VERT.ZOEKEN geen onderscheid maakt tussen kleine letters en hoofdletters.

Willen we nu exact zoeken dan hebben we daar een matrixformule met drie functies voor nodig: =INDEX, =VERGELIJKEN en =GELIJK

De matrixformule voor cel G1 : We typen =INDEX($B$1:$B$4;VERGELIJKEN(WAAR;GELIJK($A$1:$A$4;D1);0)) en drukken CTRL+SHFT+ENTER

De formule wordt nu een matrixformule (3):

{=INDEX($B$1:$B$4;VERGELIJKEN(WAAR;GELIJK($A$1:$A$4;D1);0))}

De functie =INDEX heeft drie parameters nl: Verwijzing, rij getal en (optioneel) kolom getal.

De eerste parameter “Verwijzing” is het gebied waaruit het resultaat gehaald moet worden, in ons voorbeeld zijn dat de cellen B1 tot en met B4 ($B$1:$B$4).

De tweede parameter “rij getal” is het nummer van de rij in de index waaruit het resultaat moet gehaald worden, het rij getal gaan we laten bepalen door de functie VERGELIJKEN

De functie VERGELIJKEN zoekt u naar een opgegeven item in een bereik van cellen en wordt de relatieve positie van dat item in het bereik als resultaat gegeven.
De functie vergelijken heeft drie parameters: zoekwaarde, zoeken matrix en criteriumtype_getal.

Als eerste parameter voor de functie VERGELIJKEN “zoekwaarde” geven we WAAR, als tweede parameter voor de functie VERGELIJKEN”zoeken matrix” nemen we de functie =GELIJK, de functie gelijk vergelijkt twee tekenreeksen en geeft als resultaat WAAR als de reeksen identiek zijn en ONWAAR als dit niet het geval is.

Als derde parameter voor de functie VERGELIJKEN “criteriumtype_getal” geven we een 0 in (0 = zoekt naar de eerste waarde die exact gelijk is aan zoekwaarde, 1 = zoekt naar de grootste waarde die kleiner is dan of gelijk is aan zoekwaarde en -1 = zoekt naar de kleinste waarde die groter is dan of gelijk is aan zoekwaarde.

Wanneer we nu in de formule het gedeelte GELIJK($A$1:$A$4;D1) selecteren en drukken de functietoets F9 krijgen we het volgende resultaat {ONWAAR;ONWAAR;WAAR;ONWAAR} en zien we dat er één keer “WAAR” staat , we drukken vervolgens CTRL+Z , selecteren VERGELIJKEN(WAAR;GELIJK($A$1:$A$4;D1);0) en drukken weer de functietoets F9 en krijgen als resultaat 3, het rijnummer (de tweede parameter voor index), vervolgens drukken we weer CTRL+Z en CTRL+SHIFT+ENTER om de formule te herstellen.

Ter informatie: Swotster.com denkt aan zijn cursisten, denk ook aan Swotster.com

Cursussen

• Downloading iPad Apps
• Lesson 1: Introduction to Publisher
• Lesson 65: File Formats